; Title: A Polarizing Dynamic by Center Cabinets? The Mechanism of Limited Contestation
; Version v1.00
; Published Article: Schmitt, Johannes and Franzmann T. Simon (2018): A Polarizing Dynamic by Center Cabinets? The Mechanism of Limited Contestation, in: Historical Social Research.
; Code by Johannes Schmitt
; Contact: Johannes.Schmitt@hhu.de
; NetLogo Version: 5.3.1


globals [

;; PARAMETERS ---------------------------------------------------------------------------------------------- ;;
max-ticks
information-lvl

ctyp-center
policy-seeking-weight
office-seeking-weight
vote-seeking-weight
coalition-cooperation
coalition-cooperation-distance

voter-sd
voter-modal
non-policy-mode
non-policy-weight
coalition-evaluation-mode
coalition-evaluation-weight

;; MEASUREMENTS -------------------------------------------------------------------------------------------- ;;
start-weighted-sd
last-weighted-sd
start-range
last-range
start-standard-deviation
last-standard-deviation
start-mad
last-mad

start-coalition-votes
last-coalition-votes
start-opposition-votes
last-opposition-votes
opposition-parties-right
opposition-parties-left
office-seeking-opposition
coalition-evaluation
opposition-evaluation
last-coalition-type

;;GLOBALS -------------------------------------------------------------------------------------------------- ;;
party-color-list
number-of-coalitions
voters-positions
seed
exits

equilibrium-counter
voted-list
position-list

]

breed [parties party]

parties-own [
  control             ; technical variables; used in some functions
  coalition           ; Is party member of coalition? 1: yes, 0:no
  votes-total         ; party's vote share (0-1)
  policy-pref         ; party's prefered ideological position (0-100)
  coalition-potential ; party's coalition potential (0-number of parties)
]

patches-own [         ; patches represent the voters
  party-elected       ; voter's current elected party
  non-policy-factor   ; voter's non-policy evaluation of each party (list)
  n-voters            ; number of voters on patch (recalculated as vote share)
]

;;-----------------------------------------------------------------------------------------------------------;;
;;------------------------------------------------SETUP------------------------------------------------------;;
;;-----------------------------------------------------------------------------------------------------------;;

to setup

;; MODELL INI
 clear-all
 if display? [ask patches [set pcolor white]]
 ifelse use? = "User"[user-setup][random-modell-setup]
 set exits 0

;; ITERATION INI
 calculate-election-result
 create-coalition
 reset-ticks
 if display? [show-competition]
 set seed (random 4294967296) - 2147483648
 random-seed seed
 if equilibrium-exit? [set equilibrium-counter 0]
 set office-seeking-opposition 0

;; MEASUREMENT INI
 set start-weighted-sd measure-weighted-sd
 set start-range (max [xcor] of parties with [votes-total > 0.01] - min [xcor] of parties with [votes-total > 0.01])
 set start-standard-deviation sqrt(variance [xcor] of parties)
 set start-mad mean-absolute-difference
 set start-coalition-votes sum [votes-total] of parties with [coalition = 1]
 set start-opposition-votes sum [votes-total] of parties with [coalition = 0]
 set opposition-parties-right count parties with [coalition = 0 and xcor > max [xcor] of parties with [coalition = 1]]
 set opposition-parties-left count parties with [coalition = 0 and xcor < min [xcor] of parties with [coalition = 1]]
 measure-evaluation
end

;;-----------------------------------------------------------------------------------------------------------;;
;;--------------------------------------------ITERATION------------------------------------------------------;;
;;-----------------------------------------------------------------------------------------------------------;;

to go

  if ticks = 1 and equilibrium-exit? and coalition-evaluation-mode = 0 [
    set voted-list sort [precision votes-total 6] of parties
    set position-list sort [xcor] of parties
  ]

  if ticks > 1 [
    if coalition-evaluation-mode = 1 [negative-evaluation-of-coalition-standard]
    if coalition-evaluation-mode = 2 [negative-evaluation-of-coalition-distance]
    ask parties [party-positioning]
    calculate-election-result
    if display? [show-competition]

    if equilibrium-exit? and coalition-evaluation-mode = 0 [
      ifelse voted-list = sort [precision votes-total 6] of parties and position-list = sort [xcor] of parties [set equilibrium-counter equilibrium-counter + 1][set equilibrium-counter 0]
      set voted-list sort [precision votes-total 6] of parties
      set position-list sort [xcor] of parties
      if (equilibrium-exit? and equilibrium-counter = 6) [set exits 1]
    ]
  ]

  if ticks = max-ticks or (equilibrium-exit? and equilibrium-counter = 6) [
    set last-weighted-sd measure-weighted-sd
    set last-range (max [xcor] of parties with [votes-total > 0.01] - min [xcor] of parties with [votes-total > 0.01])
    set last-standard-deviation sqrt(variance [xcor] of parties)
    set last-mad mean-absolute-difference
    set last-coalition-votes sum [votes-total] of parties with [coalition = 1]
    set last-opposition-votes sum [votes-total] of parties with [coalition = 0]
    set last-coalition-type current-coalition-type
    stop
  ]

  tick
end

;;-----------------------------------------------------------------------------------------------------------;;
;;-------------------------------------------PARTY STRATEGIES------------------------------------------------;;
;;-----------------------------------------------------------------------------------------------------------;;

to party-positioning
  no-display

  if office-seeking-weight > 0 [calculate-coalition-potential]
  let original-xcor xcor
  let max-xcor xcor
  let i xcor - information-lvl
  let connected-condition connected-coalition
  let coalition-maximum coalition-potential
  let max-calculus -999
  let max-sd-coalition sd-coalition
  let max-sub-calculus -999

  repeat (information-lvl * 2 + 1) [
    if i >= 0 and i <= 100 [
     set xcor i
     if policy-seeking-weight < 1 [calculate-election-result]
     if office-seeking-weight > 0 [calculate-coalition-potential]

     let calculus -999
     let move false
     let policy-utility (1 - abs(i - policy-pref) / 100)
     let office-utility 0
     ifelse number-of-coalitions > 0 [set office-utility (coalition-potential / number-of-coalitions)][set office-utility 0]
     if coalition = 0 [set office-seeking-opposition office-seeking-opposition + office-utility * office-seeking-weight]

     ifelse coalition = 1 and coalition-cooperation = 1 and office-seeking-weight > 0 [
       set calculus coalition-potential * office-seeking-weight
       let sub-calculus votes-total * vote-seeking-weight + (1 - abs(i - policy-pref) / 100) * policy-seeking-weight
       if calculus > max-calculus [set move true]
       if calculus = max-calculus [
         ifelse coalition-cooperation-distance = 1 [
           if max-sd-coalition > sd-coalition [set move true]
           ifelse max-sd-coalition = sd-coalition [if max-sub-calculus < sub-calculus [set move true]][if max-sub-calculus = sub-calculus and random 2 = 1[set move true]]
         ]
         [
           if max-sub-calculus < sub-calculus [set move true]
           if max-sub-calculus = sub-calculus [ifelse (abs(original-xcor - max-xcor) > abs(original-xcor - i)) [set move true][if (abs(original-xcor - max-xcor) = abs(original-xcor - i)) and random 2 = 1 [set move true]]]
         ]
       ]
       if connected-coalition = true and connected-condition = false [set move true]
       if connected-coalition = false and connected-condition = true [set move false]
     ]
     [
       set calculus (office-utility * office-seeking-weight) + (votes-total * vote-seeking-weight) + (policy-utility * policy-seeking-weight)
       if (calculus > max-calculus) [set move true]
       if calculus = max-calculus [ifelse (abs(original-xcor - max-xcor) > abs(original-xcor - i)) [set move true][if (abs(original-xcor - max-xcor) = abs(original-xcor - i)) and random 2 = 1 [set move true]]]
     ]

     if count parties with [xcor = i] > 1 [set move false]


     if move = true [
       set max-xcor xcor
       set connected-condition connected-coalition
       set max-calculus calculus
       set coalition-maximum coalition-potential
       set max-sub-calculus votes-total * vote-seeking-weight + (1 - abs(i - policy-pref) / 100) * policy-seeking-weight
       set max-sd-coalition sd-coalition
     ]
    ]
    set i i + 1
  ]

  set xcor max-xcor
  calculate-election-result
  display
end

;;-----------------------------------------------------------------------------------------------------------;;
;;----------------------------------------------MEASUREMENT--------------------------------------------------;;
;;-----------------------------------------------------------------------------------------------------------;;

to calculate-coalition-potential
  set number-of-coalitions 0
  ask parties [set coalition-potential 0]

  ask parties [
    minimal-winnig-coalitions
    set control 0
    ask parties with [control = 1][set control 0]
  ]
end

to minimal-winnig-coalitions
  ifelse (coalition = 1 and coalition-cooperation = 1 and office-seeking-weight > 0) [
      set number-of-coalitions number-of-coalitions + 1
      set coalition-potential (sum [votes-total] of parties with [coalition = 1])
  ]
  [
      let coalitions-list (list)
      set coalitions-list lput self coalitions-list

      let coalition-size votes-total
      set control 1
      let coalition-condition true

      ifelse coalition-size < 0.45 [
        while [coalition-size <= 0.45][
          ifelse coalition-cooperation = 0 or office-seeking-weight = 0 [
            ifelse min-one-of parties with [control = 0 ] [distance myself] = nobody [
              set coalition-condition false
              set coalition-size 1
            ]
            [
              ask min-one-of parties with [control = 0][distance myself][
                ;if distance myself > 25 [set coalition-condition false] // originally, limitation of maximum distance within coalition; current excluded!
                set coalitions-list lput self coalitions-list
                set coalition-size coalition-size + votes-total
                set control 1
              ]
            ]
          ]
          [
            ifelse min-one-of parties with [control = 0 and coalition = 0] [distance myself] = nobody [
              set coalition-condition false
              set coalition-size 1
            ]
            [
              ask min-one-of parties with [control = 0 and coalition = 0] [distance myself][
                ;if distance myself > 25 [set coalition-condition false] // originally, limitation of maximum distance within coalition; current excluded!
                set coalitions-list lput self coalitions-list
                set coalition-size coalition-size + votes-total
                set control 1
              ]
            ]
          ]
        ]

        if connected-potential-coalition = false [set coalition-condition false]
        if parties with [control = 1] != nobody [
          if coalition-condition = true [
            ask parties with [control = 1][set coalition-potential coalition-potential + 1]
            set number-of-coalitions number-of-coalitions + 1
          ]
        ]
      ]
      [
        set coalition-potential coalition-potential + 1
        set number-of-coalitions number-of-coalitions + 1
      ]
  ]
end

to-report minimal-winning-coalition-start
  let coalitions-list (list)
  set coalitions-list lput who coalitions-list

  let coalition-size votes-total
  set control 1

  if coalition-size <= 0.5 [
    while [coalition-size <= 0.5 and count parties with [control = 0] > 0][
      ask min-one-of parties with [control = 0][distance myself][
        set coalitions-list lput who coalitions-list
        set coalition-size coalition-size + votes-total
        set control 1
      ]
    ]
  ]
  ifelse coalition-size <= 0.5 [report false][report coalitions-list]
end

;;-----------------------------------------------------------------------------------------------------------;;
;;---------------------------------CALCULATE ELECTION RESULT-------------------------------------------------;;
;;-----------------------------------------------------------------------------------------------------------;;

to calculate-election-result
  ask patches with [n-voters > 0][set party-elected min-distance-party]
  ask parties [set votes-total sum [n-voters] of patches with [party-elected = myself]]
end

to-report min-distance-party
    let i 1
    let min-distance weight-distance distance turtle 0 item 0 non-policy-factor
    let min-party turtle 0
    repeat count parties - 1 [
      let min-i weight-distance distance turtle i item i non-policy-factor
       ifelse min-i < min-distance [
         set min-distance min-i
         set min-party turtle i
       ]
       [
         if min-i = min-distance and random 2 = 1 [
           set min-distance min-i
           set min-party turtle i
         ]
       ]
     set i i + 1
    ]
    report min-party
end

to show-competition
  if ticks = 0 [
    ask patches with [n-voters > 0 and variance non-policy-factor > 0][
      if turtle (position max non-policy-factor non-policy-factor) != nobody [set pcolor [color] of turtle (position max non-policy-factor non-policy-factor)]
    ]
  ]
  ask patches with [n-voters > 0][
    let color-p [color] of party-elected
    ask patch pxcor -2 [set pcolor color-p]
  ]
end

;;-----------------------------------------------------------------------------------------------------------;;
;;--------------------------------------------------SETUP----------------------------------------------------;;
;;-----------------------------------------------------------------------------------------------------------;;

to user-setup
  set max-ticks max-ticks?
  set information-lvl information-lvl?
  let party-n number-of-parties?

  Ifelse center-cabinet? [set ctyp-center 1][set ctyp-center 0]
  set vote-seeking-weight   vote-seeking   / (vote-seeking + office-seeking + policy-seeking)
  set policy-seeking-weight policy-seeking / (vote-seeking + office-seeking + policy-seeking)
  set office-seeking-weight office-seeking / (vote-seeking + office-seeking + policy-seeking)
  ifelse coalition-cooperation? [set coalition-cooperation 1][set coalition-cooperation 0]
  ifelse coalition-cooperation? [set coalition-cooperation-distance coalition-distance?][set coalition-cooperation-distance 0]

  set voter-sd voters-sd?
  let voters-n voters-n?
  set voter-modal voter-modal?

  set non-policy-mode non-policy-mode?
  set non-policy-weight non-policy-weight?
  set coalition-evaluation-mode coalition-evaluation-mode?
  set coalition-evaluation-weight coalition-evaluation-weight?

  create-new-parties party-n
  party-setup
  create-voter-distribution voter-sd voters-n voter-modal
  voter-setup
end

to random-modell-setup
  set max-ticks 40 + random 41
  set information-lvl 1 + random 5
  let party-n (3 + random 8)

  set ctyp-center random 2
  set vote-seeking-weight random 2
  set policy-seeking-weight random 2
  set office-seeking-weight random 2
  ifelse (vote-seeking-weight + policy-seeking-weight + office-seeking-weight = 0) [
    set policy-seeking-weight 1 / 3
    set office-seeking-weight 1 / 3
    set vote-seeking-weight 1 / 3
  ]
  [
    let sum-weights vote-seeking-weight + policy-seeking-weight + office-seeking-weight
    set policy-seeking-weight policy-seeking-weight / sum-weights
    set office-seeking-weight office-seeking-weight / sum-weights
    set vote-seeking-weight   vote-seeking-weight / sum-weights
  ]
  set coalition-cooperation random 2
  ifelse coalition-cooperation = 1 [set coalition-cooperation-distance random 2][set coalition-cooperation-distance 0]

  let voters-n 1000000
  set voter-sd 20 + random 31
  set voter-modal 1 + random 2
  set non-policy-mode random 4
  ifelse non-policy-mode > 0 [set non-policy-weight (1 + random 25)][set non-policy-weight 0]
  set coalition-evaluation-mode random 3
  ifelse coalition-evaluation-mode > 0 [set coalition-evaluation-weight (1 + random 25) / max-ticks][set coalition-evaluation-weight 0]

  create-new-parties party-n
  party-setup
  create-voter-distribution voter-sd voters-n voter-modal
  voter-setup
end

to party-setup
 set party-color-list [red blue green yellow brown grey orange lime turquoise cyan sky violet magenta pink]
 set-default-shape parties "triangle 2"
 ask parties [set policy-pref normal-rnd-value xcor 5 0 100 0]
end

to create-new-parties [#party-n]
  create-parties #party-n [
    let x -1
    while [count parties with [xcor = x] > 0 or x < 0][set x normal-rnd-value 50 25 0 100 0]
    setxy x 0
    set control 0
  ]
end

to voter-setup
 ask patches [set non-policy-factor (list)]
 if non-policy-mode  = 0 [party-non-policy-setup-1-nothing]
 if non-policy-mode  = 1 [party-non-policy-setup-2-random]
 if non-policy-mode  = 2 [party-non-policy-setup-3-distance]
 if non-policy-mode  = 3 [party-non-policy-setup-4-biased]
end

to create-voter-distribution [#sd #n #modal-value]
  if #modal-value = 1 [
    let i 0
    repeat 101 [
     ask patch i 0 [set n-voters precision ((normal-distribution i 50 #sd) * #n) 0]
     set i i + 1
    ]
  ]

  if #modal-value = 2 [
    let i 0
    let y 0
    repeat 50 [
      ask patch i 0            [set n-voters precision ((normal-distribution y 50 #sd) * #n * 0.5) 0]
      ask patch (51 + i) 0     [set n-voters precision ((normal-distribution y 50 #sd) * #n * 0.5) 0]
      set i i + 1
      set y y + 2
    ]
    ask patch 50 0 [set n-voters precision ((normal-distribution 100 50 #sd) * #n * 0.5 ) 0]
  ]

  let i 0

  if display? = true [
    set voters-positions (list)
    repeat 101 [
      ask patch i 0 [repeat n-voters [set voters-positions lput i voters-positions]]
      set i i + 1
    ]
  ]

  let sum-votes sum [n-voters] of patches
  ask patches with [n-voters > 0][set n-voters n-voters / sum-votes]

  if display? = true [
    ask patches with [n-voters > 0][
      let c (255 * (1 - (n-voters / max [n-voters] of patches)))
      set pcolor rgb c c c
    ]
    ask patches with [n-voters = 0 and pycor != 0][
      let c (255 * ((1 - ([n-voters] of patch pxcor 0 / max [n-voters] of patches) / (abs(pycor) * 0.2 + 1))))
      set pcolor rgb c c c
    ]
  ]
end

to create-coalition
  ask parties [set control 0]
  ifelse ctyp-center = 1 [
     ask min-one-of parties [xcor][set control 1]
     ask max-one-of parties [xcor][set control 1]
     let coalition-1? (list)
     ask parties with [control = 0][set coalition-1? lput who coalition-1?]
     ask parties with [control = 0][
       let coalition-2? minimal-winning-coalition-start
       if coalition-2? != false [
         if (max [xcor] of turtles with [member? who coalition-1?] - min [xcor] of turtles with [member? who coalition-1?]) > (max [xcor] of turtles with [member? who coalition-2?] - min [xcor] of turtles with [member? who coalition-2?]) [
           set coalition-1? coalition-2?
         ]
       ]
       ask parties [set control 0]
       ask min-one-of parties [xcor][set control 1]
       ask max-one-of parties [xcor][set control 1]
     ]
     ask parties with [member? who coalition-1?][set coalition 1]
  ]
  [
    let coalition1?  (list)
    let coalition2? (list)
    ask parties with [min [xcor] of turtles = xcor][set coalition1? minimal-winning-coalition-start]
    ask parties [set control 0]
    ask parties with [max [xcor] of turtles = xcor][set coalition2? minimal-winning-coalition-start]
    ifelse (max [xcor] of turtles with [member? who coalition1?] - min [xcor] of turtles with [member? who coalition1?]) <= (max [xcor] of turtles with [member? who coalition2?] - min [xcor] of turtles with [member? who coalition2?])
       [ask parties with [member? who coalition1?][set coalition 1]]
       [ask parties with [member? who coalition2?][set coalition 1]]
  ]

  ask parties [
       set size 4
       set color item who party-color-list
       if coalition = 1[ifelse coalition-cooperation = 1 [set shape "circle"][set shape "circle 2"]]
  ]
end


;;-----------------------------------------------------------------------------------------------------------;;
;;--------------------------------------Create Non-Policy Evaluation-----------------------------------------;;
;;-----------------------------------------------------------------------------------------------------------;;

to party-non-policy-setup-1-nothing
  ask patches with [n-voters > 0][repeat 20 [set non-policy-factor lput 0 non-policy-factor]]
end

to party-non-policy-setup-2-random
  ask patches with [n-voters > 0][
    repeat count parties [set non-policy-factor lput (precision random-normal 0 non-policy-weight 1) non-policy-factor]
  ]
end

to party-non-policy-setup-3-distance
  ask patches with [n-voters > 0][
    let i 0
    repeat count parties [
      set non-policy-factor lput (((50 - distance turtle i) / 50) * non-policy-weight) non-policy-factor
      set i i + 1
    ]
  ]
end

to party-non-policy-setup-4-biased
  ask parties [set control random 2]
  ask patches with [n-voters > 0][
    let i 0
    repeat count parties [
      set non-policy-factor lput (((50 - distance turtle i) / 50) * (non-policy-weight / (([control] of party i * 1.5) + 0.5))) non-policy-factor
      set i i + 1
    ]
  ]
  ask parties [set control 0]
end

to negative-evaluation-of-coalition-standard
  ask patches with [n-voters > 0][
    let i 0
    repeat count parties [
      if [coalition] of turtle i = 1[set non-policy-factor replace-item i non-policy-factor (item i non-policy-factor - coalition-evaluation-weight)]
      set i i + 1
    ]
  ]
end

to negative-evaluation-of-coalition-distance
  ask patches with [n-voters > 0][
    let i 0
    repeat count parties [
      if [coalition] of turtle i = 1 [set non-policy-factor replace-item i non-policy-factor (item i non-policy-factor - ((abs([xcor] of turtle i - pxcor) / 100) * 2) * coalition-evaluation-weight)]
      set i i + 1
    ]
  ]
end

;;-----------------------------------------------------------------------------------------------------------;;
;;----------------------------------------------Functions----------------------------------------------------;;
;;-----------------------------------------------------------------------------------------------------------;;

to measure-evaluation
  set coalition-evaluation 0
  set opposition-evaluation 0

  ask patches with [pycor = 0][
    let i 0
    repeat count parties [
      if [coalition] of turtle i = 1 [set coalition-evaluation coalition-evaluation + item i non-policy-factor]
      if [coalition] of turtle i = 0 [set opposition-evaluation opposition-evaluation + item i non-policy-factor]
      set i i + 1
    ]
  ]

  set coalition-evaluation ((coalition-evaluation / 100) / count parties with [coalition = 1])
  set opposition-evaluation ((opposition-evaluation / 100) / count parties with [coalition = 0])

end

to-report measure-weighted-sd
  let x-wmean 0
  let xs 0
  ask parties [set x-wmean x-wmean + xcor * votes-total]
  ask parties [set xs xs + (votes-total * (xcor - x-wmean) ^ 2) ]
  report sqrt (xs)
end

to-report mean-absolute-difference
  let mad 0
  ask parties [
    let mad-p 0
    ask parties [set mad-p mad-p + abs([xcor] of self - [xcor] of myself)]
    set mad mad + (mad-p / (count parties - 1))
  ]
  report mad / count parties
end

to-report normal-distribution [#x-value #mean #sd]
  report ((1 / (#sd * sqrt (2 * pi))) * e ^ (-0.5 * ((#x-value - #mean)/ #sd )^ 2))
end

to-report normal-rnd-value [#mean #sd #precision #max #min]
  let x-value #min - 100
  while [x-value < #min or x-value > #max][set x-value precision (random-normal #mean #sd) #precision]
  report x-value
end

to-report weight-distance [#distance #weight]
  report #distance - #weight
end

to-report connected-coalition
  let cmin-x 101
  let cmax-x -101
  ask min-one-of parties with [coalition = 1][xcor][set cmin-x xcor]
  ask max-one-of parties with [coalition = 1][xcor][set cmax-x xcor]
  let bool true
  ask parties with [coalition = 0][if xcor <= cmax-x and xcor > cmin-x [set bool false]]
  report bool
end

to-report connected-potential-coalition
  let cmin-x 101
  let cmax-x -101
  ask min-one-of parties with [control = 1][xcor][set cmin-x xcor]
  ask max-one-of parties with [control = 1][xcor][set cmax-x xcor]
  let bool true
  ask parties with [control = 0][if xcor <= cmax-x and xcor >= cmin-x [set bool false]]
  report bool
end

to-report sd-coalition
  ifelse count parties with [coalition = 1] = 1 [report 0][report sqrt(variance [xcor] of parties with [coalition = 1])]
end

to-report current-coalition-type
  let cmin-x 101
  let cmax-x -101
  ask min-one-of parties with [coalition = 1][xcor][set cmin-x xcor]
  ask max-one-of parties with [coalition = 1][xcor][set cmax-x xcor]

  let omin-x 101
  let omax-x -101
  ask min-one-of parties with [coalition = 0][xcor][set omin-x xcor]
  ask max-one-of parties with [coalition = 0][xcor][set omax-x xcor]

  let c-type 1
  if omin-x > cmax-x or omax-x < cmin-x [set c-type 0]
  if connected-coalition = false [set c-type 2]
  report c-type
end
@#$#@#$#@
GRAPHICS-WINDOW
12
258
1032
399
-1
5
10.0
1
10
1
1
1
0
0
0
1
0
100
-5
5
0
0
1
ticks
30.0

BUTTON
1106
259
1169
292
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

BUTTON
1043
259
1106
292
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

PLOT
12
15
488
239
Polarization
NIL
NIL
0.0
80.0
0.0
50.0
true
false
"" ""
PENS
"default" 1.0 0 -16777216 true "" "plot measure-weighted-sd"
"pen-1" 1.0 0 -13345367 true "" "plot sqrt(variance [xcor] of parties)"
"pen-2" 1.0 0 -10899396 true "" "plot (max [xcor] of parties with [votes-total > 0.01] - min [xcor] of parties with [votes-total > 0.01]) / 2"
"pen-3" 1.0 0 -8630108 true "" "plot mean-absolute-difference"

PLOT
487
15
867
239
Election Results (parties)
NIL
NIL
0.0
80.0
0.0
0.4
true
false
"" ""
PENS
"party-1-pen" 1.0 0 -2674135 true "" "plot sum [votes-total] of parties with [who = 0]"
"party-2-pen" 1.0 0 -13345367 true "" "plot sum [votes-total] of parties with [who = 1]"
"party-3-pen" 1.0 0 -10899396 true "" "plot sum [votes-total] of parties with [who = 2]"
"party-4-pen" 1.0 0 -1184463 true "" "plot sum [votes-total] of parties with [who = 3]"
"party-5-pen" 1.0 0 -6459832 true "" "plot sum [votes-total] of parties with [who = 4]"
"party-6-pen" 1.0 0 -7500403 true "" "plot sum [votes-total] of parties with [who = 5]"
"party-7-pen" 1.0 0 -955883 true "" "plot sum [votes-total] of parties with [who = 6]"
"party-8-pen" 1.0 0 -13840069 true "" "plot sum [votes-total] of parties with [who = 7]"
"party-9-pen" 1.0 0 -14835848 true "" "plot sum [votes-total] of parties with [who = 8]"
"party-10-pen" 1.0 0 -11221820 true "" "plot sum [votes-total] of parties with [who = 9]"
"party-11-pen" 1.0 0 -13791810 true "" "plot sum [votes-total] of parties with [who = 10]"
"party-12-pen" 1.0 0 -8630108 true "" "plot sum [votes-total] of parties with [who = 11]"
"party-13-pen" 1.0 0 -5825686 true "" "plot sum [votes-total] of parties with [who = 12]"
"party-14-pen" 1.0 0 -2064490 true "" "plot sum [votes-total] of parties with [who = 13]"

PLOT
867
15
1226
239
Election Results (coalition)
NIL
NIL
0.0
80.0
0.0
1.0
true
false
"" ""
PENS
"pen-1" 1.0 0 -5298144 true "" "plot 0.5"
"pen-2" 1.0 0 -16777216 true "" "plot sum [votes-total] of parties with [coalition = 1]"

PLOT
1225
15
1623
239
Party Positions
NIL
NIL
0.0
80.0
0.0
100.0
true
false
"" ""
PENS
"pen-0" 1.0 0 -2674135 true "" "plot sum [xcor] of parties with [who = 0]"
"pen-1" 1.0 0 -13345367 true "" "plot sum [xcor] of parties with [who = 1]"
"pen-2" 1.0 0 -10899396 true "" "plot sum [xcor] of parties with [who = 2]"
"pen-3" 1.0 0 -1184463 true "" "plot sum [xcor] of parties with [who = 3]"
"pen-4" 1.0 0 -6459832 true "" "plot sum [xcor] of parties with [who = 4]"
"pen-5" 1.0 0 -7500403 true "" "plot sum [xcor] of parties with [who = 5]"
"pen-6" 1.0 0 -955883 true "" "plot sum [xcor] of parties with [who = 6]"
"pen-7" 1.0 0 -13840069 true "" "plot sum [xcor] of parties with [who = 7]"
"pen-8" 1.0 0 -14835848 true "" "plot sum [xcor] of parties with [who = 8]"
"pen-9" 1.0 0 -11221820 true "" "plot sum [xcor] of parties with [who = 9]"
"pen-10" 1.0 0 -13791810 true "" "plot sum [xcor] of parties with [who = 10]"
"pen-11" 1.0 0 -8630108 true "" "plot sum [xcor] of parties with [who = 11]"
"pen-12" 1.0 0 -5825686 true "" "plot sum [xcor] of parties with [who = 12]"
"pen-13" 1.0 0 -2064490 true "" "plot sum [xcor] of parties with [who = 13]"

SWITCH
1204
371
1376
404
coalition-cooperation?
coalition-cooperation?
0
1
-1000

SLIDER
1204
299
1377
332
information-lvl?
information-lvl?
0
200
5
1
1
NIL
HORIZONTAL

SLIDER
1387
299
1565
332
voters-sd?
voters-sd?
10
75
34
1
1
NIL
HORIZONTAL

CHOOSER
1043
292
1169
337
use?
use?
"User" "Random Modell"
0

SLIDER
1203
265
1375
298
number-of-parties?
number-of-parties?
3
14
3
1
1
NIL
HORIZONTAL

SWITCH
1204
339
1376
372
center-cabinet?
center-cabinet?
1
1
-1000

SLIDER
1387
331
1565
364
voters-n?
voters-n?
200
20000
2140
10
1
NIL
HORIZONTAL

SLIDER
1043
337
1169
370
max-ticks?
max-ticks?
30
200
59
1
1
NIL
HORIZONTAL

SLIDER
1387
266
1565
299
voter-modal?
voter-modal?
1
2
1
1
1
NIL
HORIZONTAL

SLIDER
1204
477
1376
510
office-seeking
office-seeking
0
1
0
0.01
1
NIL
HORIZONTAL

SLIDER
1204
444
1376
477
vote-seeking
vote-seeking
0
1
0.5
0.01
1
NIL
HORIZONTAL

SLIDER
1204
510
1376
543
policy-seeking
policy-seeking
0
1
0.5
0.01
1
NIL
HORIZONTAL

SWITCH
1043
379
1171
412
display?
display?
0
1
-1000

PLOT
12
405
608
610
Voter distribution
NIL
NIL
0.0
10.0
0.0
10.0
true
false
"set-plot-x-range min-pxcor max-pxcor\nset-histogram-num-bars 50" ""
PENS
"voters" 1.0 1 -16777216 true "" "if display? [histogram voters-positions]"

SLIDER
1388
404
1573
437
non-policy-weight?
non-policy-weight?
0
100
6
1
1
NIL
HORIZONTAL

SLIDER
1388
472
1572
505
coalition-evaluation-weight?
coalition-evaluation-weight?
0
10
0.71
0.01
1
NIL
HORIZONTAL

SLIDER
1388
373
1573
406
non-policy-mode?
non-policy-mode?
0
3
3
1
1
NIL
HORIZONTAL

SLIDER
1388
439
1572
472
coalition-evaluation-mode?
coalition-evaluation-mode?
0
2
0
1
1
NIL
HORIZONTAL

SLIDER
1204
404
1376
437
coalition-distance?
coalition-distance?
0
1
1
1
1
NIL
HORIZONTAL

SWITCH
1043
411
1171
444
equilibrium-exit?
equilibrium-exit?
0
1
-1000

@#$#@#$#@
#A Polarizing Dynamic by Center Cabinets? The Mechanism of Limited Contestation (Johannes Schmitt and Simon T. Franzmann)

## WHAT IS IT?

Abstract: What effect does the presence of a coalition of the ideological center have on polarization in party systems? Studies of party positioning demonstrate the impact of party’s affiliation to the cabinet for its electoral campaigning. In addition, comparative studies of party systems analyzed the effects of the competitive situation between the coalition and the opposition on party competition dynamics. Nevertheless, the linkage between findings of both branches of literature is still missing. On the one hand, studies of party competition models generally focus on explaining party behavior and do not aggregate these insights. On the other hand, party system studies usually lack an analytical micro-foundation. Thus, we do not know the mechanism that drives a polity to the extreme. To find this missing link, we derive two potential explanations based on the spatial theory of party competition and Satori’s study of party systems: incumbent punishment and limited contestation. We elaborate these mechanisms with the help of an agent-based model. Then, we trace the effect of cabinet type back to the limited contestation between coalition parties. If the incumbent parties avoid contestation with each other, a center cabinet induces polarizing dynamics since the opposition then has no incentive for responsible office-seeking. Specific circumstances such as a polarized electorate and voters’ negative evaluation of the cabinet parties support this mechanism. Methodologically, our simulation study reveals three advantages of the agent-based modeling approach: (1) the uncovering of thus far implicit assumptions; (2) the possibility of analyzing causal dependencies within a complex and dynamic model; and (3) the precision of our theoretical expectations based on the micro-foundation.


###Literature

>You can find a detailed description and results in the published article:
**Schmitt, Johannes and Franzmann, Simon T. (2018): A Polarizing Dynamic by Center Cabinets? The Mechanism of Limited Contestation, in Historical Social Research.**
_(Please cite this source, if you refer to the model)_

###Additional theoretical background
Sartori, G. (1976), Parties and party systems. New York: Cambridge University Press.

Downs, A. (1957), An Economic Theory of Democracy, New York: Harper & Brothers.

Franzmann, S. T. (2011), Competition, Contest, and Cooperation. The Analytical Framework of the Issue-Market, in: Journal of Theoretical Politics 23, 317–343

Strøm, K. (1990), A Behavioral Theory of Competitive Political Parties, in: American Journal of Political Science 34, 565

## HOW IT WORKS

**General Process**: The input parameters determine the starting constellation of party competition and voters' preferences on the ideological dimension (see below description of input parameters). On this basis, the electoral competition takes place for n iterations. The starting conditions being set, the general loop starts: First,  parties position themselves based on their heuristic. Second, voters evaluate parties’ behavior and (maybe) change their voting choice in the opinion poll:

## HOW TO USE IT

###Summary
>1: Choose input parameters (manual or random)
>2: _setup_ the model
>3: _go_ to start iterations
>4: evaluate observed output


###Controls

**setup** - initiates a new simulation run based on the input parameters (important see below: _use?_).

**go** - starts the loop of iterations.

**use?** - determines whether or not the input parameters are determined by the user. If the value is _"Random Modell"_, the parameters are determined randomly. To modify the random procedure (e.g. parameters' range or the probability distribution) use the function _to random-setup_.

###Input parameters
**max-ticks?** - determines the number of iterations.

**number-of-parties?** – determines the number of parties.

**information-lvl?** – determines the level of information: "(Parties) have information about the consequences of positioning n ideological points to the left and right of their current position in each iteration" (Schmitt/Franzmann 2018)

**center-cabinet?** – determines whether there is a wing or center cabinet.

**coalition-cooperation?** - determines whether the cabinet cooperates, or not.

**coalition-distance?** - determines the maximal ideological distance within the cabinet.

**vote-seeking** - determines the proportion of parties' vote-seeking aims.

**office-seeking** - determines the proportion of parties' office-seeking aims.

**policy-seeking** - determines the proportion of parties' policy-seeking aims.

**voters-n?** - determines the number of voters.

**voters-sd?** – determines the voter distribution. Actually there are only two kinds of voter distribution realized: unimodal distribution (1) and bimodal distribution (2). Nevertheless the function can be easily adjusted to more and complex distributions (e.g. asymmetric distribution – function: “to create-voter-distribution”).

**voter-modal?** – determines the standard deviation of voters’ (2 = bimodal or 1 = unimodal) normal distribution.

**non-policy-mode?** – determines the distribution of the non-policy factor within the electorate (see Schmitt/Franzmann 2018).

**non-policy-weight?** – determines the weight of the non-policy factor.

**coalition-evaluation-mode?** – determines the distribution of the cabinet evaluation within the electorate (see Schmitt/Franzmann 2018).

**coalition-evaluation-weight?** – determines the weight of the cabinet evaluation.


## CREDITS

>(1) the theoretical model is formulated by **[Johannes Schmitt](http://www.pruf.de/unser-team/mitarbeiterinnen/johannes-schmitt.html)** (Heinrich-Heine University, Düsseldorf) and **[Dr. Simon T. Franzmann](https://www.phil-fak.uni-duesseldorf.de/pw-poguntke/homepage-simon-franzmann/)** (Heinrich-Heine University, Düsseldorf)

>(2) the model is coded by **[Johannes Schmitt](http://www.pruf.de/unser-team/mitarbeiterinnen/johannes-schmitt.html)** (Heinrich-Heine University, Düsseldorf)

>(3) We are grateful to the German Research Foundation (Deutsche Forschungsgemeinschaft, DFG) for funding this work (project title:“The influence of opposition in established democracies”; project number: 290380518; project homepage: http://www.pruf.de/abm-polarization ).




@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

sheep
false
15
Circle -1 true true 203 65 88
Circle -1 true true 70 65 162
Circle -1 true true 150 105 120
Polygon -7500403 true false 218 120 240 165 255 165 278 120
Circle -7500403 true false 214 72 67
Rectangle -1 true true 164 223 179 298
Polygon -1 true true 45 285 30 285 30 240 15 195 45 210
Circle -1 true true 3 83 150
Rectangle -1 true true 65 221 80 296
Polygon -1 true true 195 285 210 285 210 240 240 210 195 210
Polygon -7500403 true false 276 85 285 105 302 99 294 83
Polygon -7500403 true false 219 85 210 105 193 99 201 83

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

wolf
false
0
Polygon -16777216 true false 253 133 245 131 245 133
Polygon -7500403 true true 2 194 13 197 30 191 38 193 38 205 20 226 20 257 27 265 38 266 40 260 31 253 31 230 60 206 68 198 75 209 66 228 65 243 82 261 84 268 100 267 103 261 77 239 79 231 100 207 98 196 119 201 143 202 160 195 166 210 172 213 173 238 167 251 160 248 154 265 169 264 178 247 186 240 198 260 200 271 217 271 219 262 207 258 195 230 192 198 210 184 227 164 242 144 259 145 284 151 277 141 293 140 299 134 297 127 273 119 270 105
Polygon -7500403 true true -1 195 14 180 36 166 40 153 53 140 82 131 134 133 159 126 188 115 227 108 236 102 238 98 268 86 269 92 281 87 269 103 269 113

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.3.1
@#$#@#$#@
@#$#@#$#@
@#$#@#$#@
<experiments>
  <experiment name="Random Modell RUN" repetitions="4000000" runMetricsEveryStep="false">
    <setup>setup</setup>
    <go>go</go>
    <metric>max-ticks</metric>
    <metric>count parties</metric>
    <metric>count parties with [coalition = 1]</metric>
    <metric>voter-sd</metric>
    <metric>voter-modal</metric>
    <metric>ctyp-center</metric>
    <metric>information-lvl</metric>
    <metric>coalition-cooperation</metric>
    <metric>coalition-cooperation-distance</metric>
    <metric>policy-seeking-weight</metric>
    <metric>office-seeking-weight</metric>
    <metric>vote-seeking-weight</metric>
    <metric>coalition-evaluation-mode</metric>
    <metric>coalition-evaluation-weight</metric>
    <metric>non-policy-mode</metric>
    <metric>non-policy-weight</metric>
    <metric>start-coalition-votes</metric>
    <metric>last-coalition-votes</metric>
    <metric>start-opposition-votes</metric>
    <metric>last-opposition-votes</metric>
    <metric>opposition-parties-right</metric>
    <metric>opposition-parties-left</metric>
    <metric>office-seeking-opposition</metric>
    <metric>coalition-evaluation</metric>
    <metric>opposition-evaluation</metric>
    <metric>last-coalition-type</metric>
    <metric>start-weighted-sd</metric>
    <metric>last-weighted-sd</metric>
    <metric>start-range</metric>
    <metric>last-range</metric>
    <metric>start-standard-deviation</metric>
    <metric>last-standard-deviation</metric>
    <metric>start-mad</metric>
    <metric>last-mad</metric>
    <metric>seed</metric>
    <metric>exits</metric>
    <enumeratedValueSet variable="use?">
      <value value="&quot;Random Modell&quot;"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="display?">
      <value value="false"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="equilibrium-exit?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="min-pycor">
      <value value="0"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="max-pycor">
      <value value="0"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@